Ejemplos de script

Modificado el Mar., 15 Oct. a las 5:17 P. M.

En esta sección se presentarán diversos ejemplos de cómo utilizar la línea de comandos para automatizar tareas en TS Plus y optimizar sus procesos.

Uno de los casos prácticos que se abordará es la creación de un script .bat que permita a los usuarios abrir el Session Manager sin necesidad de tener acceso completo a la herramienta Admintool. Esta solución resulta ideal para delegar la tarea de desconectar sesiones a usuarios específicos, garantizando así un mayor control y seguridad en el sistema.

@echo off
cd "C:\Program Files (x86)\TSplus\UserDesktop\files"
AdminTool.exe /sessionmanager

Otro caso práctico para el uso efectivo de líneas de comando es el proceso de activación para licencias de volumen en la cual podrás activar tus diferentes equipos con TS Plus de una manera mas automatizada. En el cual se consideran las siguientes variables:

Ruta de descarga
licensekey:clave de licencia para activar, en este formato: AAAA-BBBB-CCCC-DDDD
/users: cualquier número del 1 al 50, o "ilimitado"
/edition: "Desktop", "MobileWeb" o "Enterprise"
/supportyears: Cualquier número del 0 al 3.
/activatesecurityaddon: Activar TS Plus advanced security
/comments: Especifica los comentarios que se adjuntarán a la licencia en el portal de licencias

@echo off


ECHO INSTALADOR TS PLUS VOLUME LICENSING
ECHO PC INNOVATION 2024
rem Descargar la aplicación
start "" https://dl-files.com/archives/TSplus/17.20.7.3/Setup-TSplus.exe

rem Esperar a que se descargue el archivo
timeout /t 60

rem Obtener la ruta de la carpeta Descargas del usuario actual
set "downloadFolder=%userprofile%\Downloads"

rem Mover el archivo al escritorio del usuario actual
move "%downloadFolder%\Setup-TSplus.exe" "%userprofile%\Desktop"

rem Establecer la ruta completa del archivo Setup-TSplus.exe
set "setupFile=%userprofile%\Desktop\Setup-TSplus.exe"

:inicio
cls
echo.
echo Configuracion de instalacion de TSplus
echo.

set /p volumelicensekey=Ingrese la clave de licencia de volumen: 
set /p users=Ingrese el numero de usuarios: 
set /p edition=Ingrese la edicion (MobileWeb, Enterprise o Desktop): 
set /p supportyears=Ingrese el numero de anios de soporte: 
set /p activatesecurityaddon=Activar add-on de seguridad (si/no): 
set /p comments="Agregar comentarios: " 

if /i "%activatesecurityaddon%"=="si" (
    set activatesecurityaddon=yes /edition=Ultimate
) else (
    set activatesecurityaddon=no
)

echo.
echo Resumen de la configuracion:
echo Clave de licencia: %volumelicensekey%
echo Numero de usuarios: %users%
echo Edicion: %edition%
echo Anios de soporte: %supportyears%
echo Add-on de seguridad: %activatesecurityaddon%
echo Comentarios: %comments%

echo.
echo ¿Desea continuar con esta configuracion? (si/no)
set /p continuar=

if /i "%continuar%"=="si" (
    start "" /d "%userprofile%\Desktop" "%setupFile%"  /volumelicensekey=%volumelicensekey% /users=%users% /edition=%edition% /supportyears=%supportyears% /activatesecurityaddon=%activatesecurityaddon% /comments="%comments%" /VERYSILENT /NORESTART /port=31972 /webport=41972
) else (
    goto inicio
)

pause
exit

Un caso práctico para el proceso de desinstalación de TS Plus es el siguiente, en el cual podremos desactivar la licencia de volumen que previamente activamos y posteriormente proceder con la desinstalación

@echo off
ECHO DESINSTALADOR TS PLUS VOLUME LICENSING
ECHO PC INNOVATION 2024

:inicio
cls
echo.
echo Configuracion de desinstalacion de TSplus
echo.

set /p volumelicensekey=Ingrese la clave de licencia de volumen: 

"C:\Program Files (x86)\TSplus\UserDesktop\files\AdminTool.exe" /vl /disable %volumelicensekey%

start "" "C:\Program Files (x86)\TSplus\unins000.exe" /F /VERYSILENT /NORESTART

echo Desinstalación completada.
pause

O un caso mas sencillo para desinstalar como el siguiente:

"%ProgramFiles(x86)%\TSplus\unins000.exe" /VERYSILENT /SUPPRESSMSGBOXES /NORESTART

Para poder programar un respaldo de manera silenciosa y automática, podrás crear un script el cual puedas realizarlo de la manera que mas se te facilite, tal como se muestra en el siguiente apartado:

@echo off
setlocal enabledelayedexpansion

:: Obtiene la fecha y hora del sistema
for /f "tokens=2 delims==" %%I in ('wmic os get localdatetime /value ^| find "="') do set datetime=%%I
set fecha=!datetime:~0,8!
set hora=!datetime:~8,6!

:: Formatea la fecha y la hora para el nombre de la carpeta
set fecha=!fecha:~0,4!-!fecha:~4,2!-!fecha:~6,2!
set hora=!hora:~0,2!-!hora:~2,2!-!hora:~4,2!

:: Crea la carpeta con la fecha y hora
set backupFolder=C:\TSplus\CustomBackupFolder\Backup_!fecha!_!hora!
mkdir "!backupFolder!"

:: Ejecuta el comando de respaldo
"C:\Program Files (x86)\TSplus\UserDesktop\files\AdminTool.exe" /backup "!backupFolder!" /silent

endlocal